-spec casefold(String :: unicode:chardata()) -> unicode:chardata().

Converts String to a case-agnostic comparable string. Function casefold/1 is preferred over lowercase/1 when two strings are to be compared for equality. See also equal/4.

Example:

1> string:casefold("Ω and ẞ SHARP S").
"ω and ss sharp s"

-spec chomp(String :: unicode:chardata()) -> unicode:chardata().

Returns a string where any trailing \n or \r\n have been removed from String.

Example:

182> string:chomp(<<"\nHello\n\n">>).
<<"\nHello">>
183> string:chomp("\nHello\r\r\n").
"\nHello\r"

-spec equal(A, B) -> boolean() when A :: unicode:chardata(), B :: unicode:chardata().

Equivalent to equal(A, B, true).

-spec equal(A, B, IgnoreCase) -> boolean()
         when A :: unicode:chardata(), B :: unicode:chardata(), IgnoreCase :: boolean().

Equivalent to equal(A, B, IgnoreCase, none).

-spec equal(A, B, IgnoreCase, Norm) -> boolean()
         when
             A :: unicode:chardata(),
             B :: unicode:chardata(),
             IgnoreCase :: boolean(),
             Norm :: none | nfc | nfd | nfkc | nfkd.

Returns true if A and B are equal, otherwise false.

If IgnoreCase is true the function does casefolding on the fly before the equality test.

If Norm is not none the function applies normalization on the fly before the equality test. There are four available normalization forms: nfc, nfd, nfkc, and nfkd.

Example:

1> string:equal("åäö", <<"åäö"/utf8>>).
true
2> string:equal("åäö", unicode:characters_to_nfd_binary("åäö")).
false
3> string:equal("åäö", unicode:characters_to_nfd_binary("ÅÄÖ"), true, nfc).
true

-spec find(String, SearchPattern) -> unicode:chardata() | nomatch
        when String :: unicode:chardata(), SearchPattern :: unicode:chardata().

Equivalent to find(String, SearchPattern, leading).

-spec find(String, SearchPattern, Dir) -> unicode:chardata() | nomatch
        when String :: unicode:chardata(), SearchPattern :: unicode:chardata(), Dir :: direction().

Removes anything before SearchPattern in String and returns the remainder of the string or nomatch if SearchPattern is not found. Dir, which can be leading or trailing, indicates from which direction characters are to be searched.

Example:

1> string:find("ab..cd..ef", ".").
"..cd..ef"
2> string:find(<<"ab..cd..ef">>, "..", trailing).
<<"..ef">>
3> string:find(<<"ab..cd..ef">>, "x", leading).
nomatch
4> string:find("ab..cd..ef", "x", trailing).
nomatch

-spec is_empty(String :: unicode:chardata()) -> boolean().

Returns true if String is the empty string, otherwise false.

Example:

1> string:is_empty("foo").
false
2> string:is_empty(["",<<>>]).
true

-spec jaro_similarity(String1, String2) -> Similarity
                   when
                       String1 :: unicode:chardata(),
                       String2 :: unicode:chardata(),
                       Similarity :: float().

Returns a float between +0.0 and 1.0 representing the Jaro similarity between the given strings. Strings with many letters in common relative to their lengths will score closer to 1.0.

The Jaro distance between two strings can be calculated with JaroDistance = 1.0-JaroSimilarity.

Example:

1> string:jaro_similarity("ditto", "ditto").
1.0
2> string:jaro_similarity("foo", "bar").
+0.0
3> string:jaro_similarity("michelle", "michael").
0.8690476190476191
4> string:jaro_similarity(<<"Édouard"/utf8>>, <<"Claude">>).
0.5317460317460317

-spec length(String :: unicode:chardata()) -> non_neg_integer().

Returns the number of grapheme clusters in String.

Example:

1> string:length("ß↑e̊").
3
2> string:length(<<195,159,226,134,145,101,204,138>>).
3

-spec lexemes(String :: unicode:chardata(), SeparatorList :: [grapheme_cluster()]) ->
           [unicode:chardata()].

Returns a list of lexemes in String, separated by the grapheme clusters in SeparatorList.

Notice that, as shown in this example, two or more adjacent separator graphemes clusters in String are treated as one. That is, there are no empty strings in the resulting list of lexemes. See also split/3 which returns empty strings.

Notice that [$\r,$\n] is one grapheme cluster.

Example:

1> string:lexemes("abc de̊fxxghix jkl\r\nfoo", "x e" ++ [[$\r,$\n]]).
["abc","de̊f","ghi","jkl","foo"]
2> string:lexemes(<<"abc de̊fxxghix jkl\r\nfoo"/utf8>>, "x e" ++ [$\r,$\n]).
[<<"abc">>,<<"de̊f"/utf8>>,<<"ghi">>,<<"jkl\r\nfoo">>]

-spec lowercase(String :: unicode:chardata()) -> unicode:chardata().

Converts String to lowercase.

Notice that function casefold/1 should be used when converting a string to be tested for equality.

Example:

2> string:lowercase(string:uppercase("Michał")).
"michał"

-spec next_codepoint(String :: unicode:chardata()) ->
                  maybe_improper_list(char(), unicode:chardata()) | {error, unicode:chardata()}.

Returns the first codepoint in String and the rest of String in the tail. Returns an empty list if String is empty or an {error, String} tuple if the next byte is invalid.

Example:

1> string:next_codepoint(unicode:characters_to_binary("e̊fg")).
[101|<<"̊fg"/utf8>>]

-spec next_grapheme(String :: unicode:chardata()) ->
                 maybe_improper_list(grapheme_cluster(), unicode:chardata()) |
                 {error, unicode:chardata()}.

Returns the first grapheme cluster in String and the rest of String in the tail. Returns an empty list if String is empty or an {error, String} tuple if the next byte is invalid.

Example:

1> string:next_grapheme(unicode:characters_to_binary("e̊fg")).
["e̊"|<<"fg">>]

-spec nth_lexeme(String, N, SeparatorList) -> unicode:chardata()
              when
                  String :: unicode:chardata(),
                  N :: non_neg_integer(),
                  SeparatorList :: [grapheme_cluster()].

Returns lexeme number N in String, where lexemes are separated by the grapheme clusters in SeparatorList.

Example:

1> string:nth_lexeme("abc.de̊f.ghiejkl", 3, ".e").
"ghi"

-spec pad(String, Length) -> unicode:charlist() when String :: unicode:chardata(), Length :: integer().

Equivalent to pad(String, Length, trailing).

-spec pad(String, Length, Dir) -> unicode:charlist()
       when String :: unicode:chardata(), Length :: integer(), Dir :: direction() | both.

Equivalent to pad(String, Length, Dir, $ ).

-spec pad(String, Length, Dir, Char) -> unicode:charlist()
       when
           String :: unicode:chardata(),
           Length :: integer(),
           Dir :: direction() | both,
           Char :: grapheme_cluster().

Pads String to Length with grapheme cluster Char. Dir, which can be leading, trailing, or both, indicates where the padding should be added.

Example:

1> string:pad(<<"He̊llö"/utf8>>, 8).
[<<72,101,204,138,108,108,195,182>>,32,32,32]
2> io:format("'~ts'~n",[string:pad("He̊llö", 8, leading)]).
'   He̊llö'
3> io:format("'~ts'~n",[string:pad("He̊llö", 8, both)]).
' He̊llö  '

-spec prefix(String :: unicode:chardata(), Prefix :: unicode:chardata()) -> nomatch | unicode:chardata().

If Prefix is the prefix of String, removes it and returns the remainder of String, otherwise returns nomatch.

Example:

1> string:prefix(<<"prefix of string">>, "pre").
<<"fix of string">>
2> string:prefix("pre", "prefix").
nomatch

-spec replace(String, SearchPattern, Replacement) -> [unicode:chardata()]
           when
               String :: unicode:chardata(),
               SearchPattern :: unicode:chardata(),
               Replacement :: unicode:chardata().

Equivalent to replace(String, SearchPattern, Replacement, leading).

-spec replace(String, SearchPattern, Replacement, Where) -> [unicode:chardata()]
           when
               String :: unicode:chardata(),
               SearchPattern :: unicode:chardata(),
               Replacement :: unicode:chardata(),
               Where :: direction() | all.

Replaces SearchPattern in String with Replacement. Where, indicates whether the leading, the trailing or all encounters of SearchPattern are to be replaced.

Can be implemented as:

lists:join(Replacement, split(String, SearchPattern, Where)).

Example:

1> string:replace(<<"ab..cd..ef">>, "..", "*").
[<<"ab">>,"*",<<"cd..ef">>]
2> string:replace(<<"ab..cd..ef">>, "..", "*", all).
[<<"ab">>,"*",<<"cd">>,"*",<<"ef">>]

-spec reverse(String :: unicode:chardata()) -> [grapheme_cluster()].

Returns the reverse list of the grapheme clusters in String.

Example:

1> Reverse = string:reverse(unicode:characters_to_nfd_binary("ÅÄÖ")).
[[79,776],[65,776],[65,778]]
2> io:format("~ts~n",[Reverse]).
ÖÄÅ

-spec slice(String, Start) -> Slice
         when
             String :: unicode:chardata(), Start :: non_neg_integer(), Slice :: unicode:chardata().

Equivalent to slice(String, Length, infinity).

-spec slice(String, Start, Length) -> Slice
         when
             String :: unicode:chardata(),
             Start :: non_neg_integer(),
             Length :: infinity | non_neg_integer(),
             Slice :: unicode:chardata().

Returns a substring of String of at most Length grapheme clusters, starting at position Start.

Example:

1> string:slice(<<"He̊llö Wörld"/utf8>>, 4).
<<"ö Wörld"/utf8>>
2> string:slice(["He̊llö ", <<"Wörld"/utf8>>], 4,4).
"ö Wö"
3> string:slice(["He̊llö ", <<"Wörld"/utf8>>], 4,50).
"ö Wörld"

-spec split(String, SearchPattern) -> [unicode:chardata()]
         when String :: unicode:chardata(), SearchPattern :: unicode:chardata().

Equivalent to split(String, SearchPattern, leading).

-spec split(String, SearchPattern, Where) -> [unicode:chardata()]
         when
             String :: unicode:chardata(),
             SearchPattern :: unicode:chardata(),
             Where :: direction() | all.

Splits String where SearchPattern is encountered and return the remaining parts. Where, default leading, indicates whether the leading, the trailing or all encounters of SearchPattern will split String.

Example:

0> string:split("ab..bc..cd", "..").
["ab","bc..cd"]
1> string:split(<<"ab..bc..cd">>, "..", trailing).
[<<"ab..bc">>,<<"cd">>]
2> string:split(<<"ab..bc....cd">>, "..", all).
[<<"ab">>,<<"bc">>,<<>>,<<"cd">>]

-spec take(String, Characters) -> {Leading, Trailing}
        when
            String :: unicode:chardata(),
            Characters :: [grapheme_cluster()],
            Leading :: unicode:chardata(),
            Trailing :: unicode:chardata().

Equivalent to take(String, Characters, false).

-spec take(String, Characters, Complement) -> {Leading, Trailing}
        when
            String :: unicode:chardata(),
            Characters :: [grapheme_cluster()],
            Complement :: boolean(),
            Leading :: unicode:chardata(),
            Trailing :: unicode:chardata().

Equivalent to take(String, Characters, Complement, leading).

-spec take(String, Characters, Complement, Dir) -> {Leading, Trailing}
        when
            String :: unicode:chardata(),
            Characters :: [grapheme_cluster()],
            Complement :: boolean(),
            Dir :: direction(),
            Leading :: unicode:chardata(),
            Trailing :: unicode:chardata().

Takes characters from String as long as the characters are members of set Characters or the complement of set Characters. Dir, which can be leading or trailing, indicates from which direction characters are to be taken.

Example:

5> string:take("abc0z123", lists:seq($a,$z)).
{"abc","0z123"}
6> string:take(<<"abc0z123">>, lists:seq($0,$9), true, leading).
{<<"abc">>,<<"0z123">>}
7> string:take("abc0z123", lists:seq($0,$9), false, trailing).
{"abc0z","123"}
8> string:take(<<"abc0z123">>, lists:seq($a,$z), true, trailing).
{<<"abc0z">>,<<"123">>}

-spec titlecase(String :: unicode:chardata()) -> unicode:chardata().

Converts String to titlecase.

Example:

1> string:titlecase("ß is a SHARP s").
"Ss is a SHARP s"

-spec to_float(String) -> {Float, Rest} | {error, Reason}
            when
                String :: unicode:chardata(),
                Float :: float(),
                Rest :: unicode:chardata(),
                Reason :: no_float | badarg.

Argument String is expected to start with a valid text represented float (the digits are ASCII values). Remaining characters in the string after the float are returned in Rest.

Example:

1> {F1,Fs} = string:to_float("1.0-1.0e-1"),
1> {F2,[]} = string:to_float(Fs),
1> F1+F2.
0.9
2> string:to_float("3/2=1.5").
{error,no_float}
3> string:to_float("-1.5eX").
{-1.5,"eX"}

-spec to_graphemes(String :: unicode:chardata()) -> [grapheme_cluster()].

Converts String to a list of grapheme clusters.

Example:

1> string:to_graphemes("ß↑e̊").
[223,8593,[101,778]]
2> string:to_graphemes(<<"ß↑e̊"/utf8>>).
[223,8593,[101,778]]

-spec to_integer(String) -> {Int, Rest} | {error, Reason}
              when
                  String :: unicode:chardata(),
                  Int :: integer(),
                  Rest :: unicode:chardata(),
                  Reason :: no_integer | badarg.

Argument String is expected to start with a valid text represented integer (the digits are ASCII values). Remaining characters in the string after the integer are returned in Rest.

Example:

1> {I1,Is} = string:to_integer("33+22"),
1> {I2,[]} = string:to_integer(Is),
1> I1-I2.
11
2> string:to_integer("0.5").
{0,".5"}
3> string:to_integer("x=2").
{error,no_integer}

-spec trim(String) -> unicode:chardata() when String :: unicode:chardata().

Equivalent to trim(String, both).

-spec trim(String, Dir) -> unicode:chardata()
        when String :: unicode:chardata(), Dir :: direction() | both.

Equivalent to trim(String, Dir, Whitespace}) where Whitespace is the set of nonbreakable whitespace codepoints, defined as Pattern_White_Space in Unicode Standard Annex #31.

-spec trim(String, Dir, Characters) -> unicode:chardata()
        when
            String :: unicode:chardata(),
            Dir :: direction() | both,
            Characters :: [grapheme_cluster()].

Returns a string, where leading or trailing, or both, Characters have been removed.

Dir which can be leading, trailing, or both, indicates from which direction characters are to be removed.

Note that [$\r,$\n] is one grapheme cluster according to the Unicode Standard.

Example:

1> string:trim("\t  Hello  \n").
"Hello"
2> string:trim(<<"\t  Hello  \n">>, leading).
<<"Hello  \n">>
3> string:trim(<<".Hello.\n">>, trailing, "\n.").
<<".Hello">>

-spec uppercase(String :: unicode:chardata()) -> unicode:chardata().

Converts String to uppercase.

See also titlecase/1.

Example:

1> string:uppercase("Michał").
"MICHAŁ"