-spec accept(ListenSocket) -> {ok, Socket} | {error, Reason}
          when
              ListenSocket :: socket(),
              Socket :: socket(),
              Reason :: closed | system_limit | inet:posix().

Equivalent to accept/2.

-spec accept(ListenSocket, Timeout) -> {ok, Socket} | {error, Reason}
          when
              ListenSocket :: socket(),
              Timeout :: timeout(),
              Socket :: socket(),
              Reason :: closed | timeout | system_limit | inet:posix().

Accepts an incoming connection request on a listening socket. Socket must be a socket returned from listen/2. Timeout specifies a time-out value in milliseconds. Defaults to infinity.

Returns:

• {ok, Socket} if a connection is established
• {error, closed} if ListenSocket is closed
• {error, timeout} if no connection is established within the specified time
• {error, system_limit} if all available ports in the Erlang emulator are in use
• A POSIX error value if something else goes wrong, see inet for possible error values

Packets can be sent to the returned socket Socket using send/2. Packets sent from the peer are delivered as messages (unless {active, false} is specified in the option list for the listening socket, in which case packets are retrieved by calling recv/2):

{tcp, Socket, Data}

Note

The accept call does not have to be issued from the socket owner process. Using version 5.5.3 and higher of the emulator, multiple simultaneous accept calls can be issued from different processes, which allows for a pool of acceptor processes handling incoming connections.

-spec close(Socket) -> ok when Socket :: socket().

Closes a TCP socket.

Note that in most implementations of TCP, doing a close does not guarantee that any data sent is delivered to the recipient before the close is detected at the remote side. If you want to guarantee delivery of the data to the recipient there are two common ways to achieve this.

1. Use gen_tcp:shutdown(Sock, write) to signal that no more data is to be sent and wait for the read side of the socket to be closed.
2. Use the socket option {packet, N} (or something similar) to make it possible for the receiver to close the connection when it knowns it has received all the data.

-spec connect(SockAddr, Opts) -> {ok, Socket} | {error, Reason}
           when
               SockAddr :: socket:sockaddr_in() | socket:sockaddr_in6(),
               Opts :: [inet:inet_backend() | connect_option()],
               Socket :: socket(),
               Reason :: inet:posix().

Equivalent to connect/3.

-spec connect(Address, Port, Opts) -> {ok, Socket} | {error, Reason}
           when
               Address :: inet:socket_address() | inet:hostname(),
               Port :: inet:port_number(),
               Opts :: [inet:inet_backend() | connect_option()],
               Socket :: socket(),
               Reason :: inet:posix();
       (SockAddr, Opts, Timeout) -> {ok, Socket} | {error, Reason}
           when
               SockAddr :: socket:sockaddr_in() | socket:sockaddr_in6(),
               Opts :: [inet:inet_backend() | connect_option()],
               Timeout :: timeout(),
               Socket :: socket(),
               Reason :: timeout | inet:posix().

Connects to a server according to SockAddr. This is primarily intended for link local IPv6 addresses (which require the scope-id), socket:sockaddr_in6/0. But for completeness, we also support IPv4, socket:sockaddr_in/0.

The options available are the same as for connect/3,4.

Note

Keep in mind that if the underlying OS connect() call returns a timeout, gen_tcp:connect will also return a timeout (i.e. {error, etimedout}), even if a larger Timeout was specified.

Note

The default values for options specified to connect can be affected by the Kernel configuration parameter inet_default_connect_options. For details, see inet.

-spec connect(Address, Port, Opts, Timeout) -> {ok, Socket} | {error, Reason}
           when
               Address :: inet:socket_address() | inet:hostname(),
               Port :: inet:port_number(),
               Opts :: [inet:inet_backend() | connect_option()],
               Timeout :: timeout(),
               Socket :: socket(),
               Reason :: timeout | inet:posix().

Connects to a server on TCP port Port on the host with IP address Address. Argument Address can be a hostname or an IP address.

The following options are available:

• {ip, Address} - If the host has many network interfaces, this option specifies which one to use.

• {ifaddr, Address} - Same as {ip, Address}. If the host has many network interfaces, this option specifies which one to use.

  However, if this instead is an socket:sockaddr_in/0 or socket:sockaddr_in6/0 this takes precedence over any value previously set with the ip and port options. If these options (ip or/and port) however comes after this option, they may be used to update their corresponding fields of this options (for ip, the addr field, and for port, the port field).

• {fd, integer() >= 0} - If a socket has somehow been connected without using gen_tcp, use this option to pass the file descriptor for it. If {ip, Address} and/or {port, port_number()} is combined with this option, the fd is bound to the specified interface and port before connecting. If these options are not specified, it is assumed that the fd is already bound appropriately.

• inet - Sets up the socket for IPv4.

• inet6 - Sets up the socket for IPv6.

• local - Sets up a Unix Domain Socket. See inet:local_address/0

• {port, Port} - Specifies which local port number to use.

• {tcp_module, module()} - Overrides which callback module is used. Defaults to inet_tcp for IPv4 and inet6_tcp for IPv6.

• Opt - See inet:setopts/2.

Packets can be sent to the returned socket Socket using send/2. Packets sent from the peer are delivered as messages:

{tcp, Socket, Data}

If the socket is in {active, N} mode (see inet:setopts/2 for details) and its message counter drops to 0, the following message is delivered to indicate that the socket has transitioned to passive ({active, false}) mode:

{tcp_passive, Socket}

If the socket is closed, the following message is delivered:

{tcp_closed, Socket}

If an error occurs on the socket, the following message is delivered (unless {active, false} is specified in the option list for the socket, in which case packets are retrieved by calling recv/2):

{tcp_error, Socket, Reason}

The optional Timeout parameter specifies a time-out in milliseconds. Defaults to infinity.

Note

Keep in mind that if the underlying OS connect() call returns a timeout, gen_tcp:connect will also return a timeout (i.e. {error, etimedout}), even if a larger Timeout was specified.

Note

The default values for options specified to connect can be affected by the Kernel configuration parameter inet_default_connect_options. For details, see inet.

-spec controlling_process(Socket, Pid) -> ok | {error, Reason}
                       when
                           Socket :: socket(),
                           Pid :: pid(),
                           Reason :: closed | not_owner | badarg | inet:posix().

Assigns a new controlling process Pid to Socket. The controlling process is the process that receives messages from the socket. If called by any other process than the current controlling process, {error, not_owner} is returned. If the process identified by Pid is not an existing local pid, {error, badarg} is returned. {error, badarg} may also be returned in some cases when Socket is closed during the execution of this function.

If the socket is set in active mode, this function will transfer any messages in the mailbox of the caller to the new controlling process. If any other process is interacting with the socket while the transfer is happening, the transfer may not work correctly and messages may remain in the caller's mailbox. For instance changing the sockets active mode before the transfer is complete may cause this.

-spec listen(Port, Options) -> {ok, ListenSocket} | {error, Reason}
          when
              Port :: inet:port_number(),
              Options :: [inet:inet_backend() | listen_option()],
              ListenSocket :: socket(),
              Reason :: system_limit | inet:posix().

Sets up a socket to listen on port Port on the local host.

If Port == 0, the underlying OS assigns an available port number, use inet:port/1 to retrieve it.

The following options are available:

• list - Received Packet is delivered as a list.

• binary - Received Packet is delivered as a binary.

• {backlog, B} - B is an integer >= 0. The backlog value defines the maximum length that the queue of pending connections can grow to. Defaults to 5.

• inet6 - Sets up the socket for IPv6.

• inet - Sets up the socket for IPv4.

• {fd, Fd} - If a socket has somehow been connected without using gen_tcp, use this option to pass the file descriptor for it.

• {ip, Address} - If the host has many network interfaces, this option specifies which one to listen on.

• {port, Port} - Specifies which local port number to use.

• {ifaddr, Address} - Same as {ip, Address}. If the host has many network interfaces, this option specifies which one to use.

  However, if this instead is an socket:sockaddr_in/0 or socket:sockaddr_in6/0 this takes precedence over any value previously set with the ip and port options. If these options (ip or/and port) however comes after this option, they may be used to update their corresponding fields of this options (for ip, the addr field, and for port, the port field).

• {tcp_module, module()} - Overrides which callback module is used. Defaults to inet_tcp for IPv4 and inet6_tcp for IPv6.

• Opt - See inet:setopts/2.

The returned socket ListenSocket should be used in calls to accept/1,2 to accept incoming connection requests.

Note

The default values for options specified to listen can be affected by the Kernel configuration parameter inet_default_listen_options. For details, see inet.

-spec recv(Socket, Length) -> {ok, Packet} | {error, Reason}
        when
            Socket :: socket(),
            Length :: non_neg_integer(),
            Packet :: string() | binary() | HttpPacket,
            Reason :: closed | inet:posix(),
            HttpPacket :: term().

Equivalent to recv/3.

-spec recv(Socket, Length, Timeout) -> {ok, Packet} | {error, Reason}
        when
            Socket :: socket(),
            Length :: non_neg_integer(),
            Timeout :: timeout(),
            Packet :: string() | binary() | HttpPacket,
            Reason :: closed | timeout | inet:posix(),
            HttpPacket :: term().

Receives a packet from a socket in passive mode. A closed socket is indicated by return value {error, closed}. If the socket is not in passive mode, the return value is {error, einval}.

Argument Length is only meaningful when the socket is in raw mode and denotes the number of bytes to read. If Length is 0, all available bytes are returned. If Length > 0, exactly Length bytes are returned, or an error; possibly discarding less than Length bytes of data when the socket is closed from the other side.

The optional Timeout parameter specifies a time-out in milliseconds. Defaults to infinity.

Any process can receive data from a passive socket, even if that process is not the controlling process of the socket. However, only one process can call this function on a socket at any given time. Using simultaneous calls to recv is not recommended as its behavior is dependent on the socket implementation, and could return errors such as {error, ealready}.

-spec send(Socket, Packet) -> ok | {error, Reason}
        when
            Socket :: socket(),
            Packet :: iodata(),
            Reason :: closed | {timeout, RestData} | inet:posix(),
            RestData :: binary() | erlang:iovec().

Sends a packet on a socket.

There is no send call with a time-out option, use socket option send_timeout if time-outs are desired. See section Examples.

The return value {error, {timeout, RestData}} can only be returned when inet_backend = socket.

Note

Non-blocking send.

If the user tries to send more data than there is room for in the OS send buffers, the 'rest data' is put into (inet driver) internal buffers and later sent in the background. The function immediately returns ok (not informing the caller that not all of the data was actually sent). Any issue while sending the 'rest data' is maybe returned later.

When using inet_backend = socket, the behaviour is different. There is no buffering done (like the inet-driver does), instead the caller will "hang" until all of the data has been sent or send timeout (as specified by the send_timeout option) expires (the function can hang even when using 'inet' backend if the internal buffers are full).

If this happens when using packet =/= raw, we have a partial package written. A new package therefore must not be written at this point, as there is no way for the peer to distinguish this from the data portion of the current package. Instead, set package to raw, send the rest data (as raw data) and then set package to the wanted package type again.

-spec shutdown(Socket, How) -> ok | {error, Reason}
            when Socket :: socket(), How :: read | write | read_write, Reason :: inet:posix().

Closes a socket in one or two directions.

How == write means closing the socket for writing, reading from it is still possible.

If How == read or there is no outgoing data buffered in the Socket port, the socket is shut down immediately and any error encountered is returned in Reason.

If there is data buffered in the socket port, the attempt to shutdown the socket is postponed until that data is written to the kernel socket send buffer. If any errors are encountered, the socket is closed and {error, closed} is returned on the next recv/2 or send/2.

Option {exit_on_close, false} is useful if the peer has done a shutdown on the write side.

Note

Async shutdown write (write or read_write).

If the shutdown attempt is made while the inet-driver is sending buffered data in the background, the shutdown is postponed until all buffered data has been sent. The function immediately returns ok and the caller is not informed (that the shutdown has not yet been performed).

When using inet_backend = socket, the behaviour is different. A shutdown with How == write | read_write, the operation will take immediate effect (unlike the inet-driver, which basically saves the operation for later).