7 Config Files
7.1 General
The Common Test framework uses configuration files to describe data related to a test and/or an SUT (System Under Test). The configuration data makes it possible to change properties without changing the test program itself. Configuration data can for example be:
- Addresses to the test plant or other instruments
- Filenames for files needed by the test
- Program names for programs that shall be run by the test
- Any other variable that is needed by the test
7.2 Syntax
A configuration file can contain any number of elements of the type:
{Key,Value}.where
Key = atom()
Value = term() | [{Key,Value}]7.3 Requiring and reading configuration data
In a test suite, one must require that a configuration variable exists before attempting to read the associated value in a test case.
require is an assert statement that can be part of the test suite info function or test case info function. If the required variable is not available, the test is skipped (unless a default value has been specified, see the test case info function chapter for details). There is also a function ct:require/[1,2] which can be called from a test case in order to check if a specific variable is available. The return value from this function must be checked explicitly and appropriate action be taken depending on the result (e.g. to skip the test case if the variable in question doesn't exist).
A require statement in the test suite info- or test case info-list should look like this: {require,Required} or {require,Name,Required}. The arguments Name and Required are the same as the arguments to ct:require/[1,2] which are described in the reference manual for ct. Name becomes an alias for the configuration variable Required, and can be used as reference to the configuration data value. The configuration variable may be associated with an arbitrary number of alias names, but each name must be unique within the same test suite. There are two main uses for alias names:
- They may be introduced to identify connections (see below).
- They may used to help adapt configuration data to a test suite (or test case) and improve readability.
To read the value of a config variable, use the function get_config/[1,2,3] which is also described in the reference manual for ct.
Example:
suite() ->
[{require, domain, 'CONN_SPEC_DNS_SUFFIX'}].
...
testcase(Config) ->
Domain = ct:get_config(domain),
...7.4 Using configuration variables defined in multiple files
If a configuration variable is defined in multiple files and you want to access all possible values, you may use the ct:get_config/3 function and specify all in the options list. The values will then be returned in a list and the order of the elements corresponds to the order that the config files were specified at startup. Please see the ct reference manual for details.
7.5 Encrypted configuration files
It is possible to encrypt configuration files containing sensitive data if these files must be stored in open and shared directories.
Call ct:encrypt_config_file/[2,3] to have Common Test encrypt a specified file using the DES3 function in the OTP crypto application. The encrypted file can then be used as a regular configuration file, in combination with other encrypted files or normal text files. The key for decrypting the configuration file must be provided when running the test, however. This can be done by means of the decrypt_key or decrypt_file flag/option, or a key file in a predefined location.
Common Test also provides decryption functions, ct:decrypt_config_file/[2,3], for recreating the original text files.
Please see the ct reference manual for more information.
7.6 Opening connections by using configuration data
There are two different methods for opening a connection by means of the support functions in e.g. ct_ssh, ct_ftp, and ct_telnet:
- Using a configuration target name (an alias) as reference.
- Using the configuration variable as reference.
When a target name is used for referencing the configuration data (that specifies the connection to be opened), the same name may be used as connection identity in all subsequent calls related to the connection (also for closing it). It's only possible to have one open connection per target name. If attempting to open a new connection using a name already associated with an open connection, Common Test will return the already existing handle so that the previously opened connection will be used. This is a practical feature since it makes it possible to call the function for opening a particular connection whenever useful. An action like this will not necessarily open any new connections unless it's required (which could be the case if e.g. the previous connection has been closed unexpectedly by the server). Another benefit of using named connections is that it's not necessary to pass handle references around in the suite for these connections.
When a configuration variable name is used as reference to the data specifying the connection, the handle returned as a result of opening the connection must be used in all subsequent calls (also for closing the connection). Repeated calls to the open function with the same variable name as reference will result in multiple connections being opened. This can be useful e.g. if a test case needs to open multiple connections to the same server on the target node (using the same configuration data for each connection).
7.7 Examples
A config file for using the FTP client to access files on a remote host could look like this:
{ftp_host, [{ftp,"targethost"},
{username,"tester"},
{password,"letmein"}]}.
{lm_directory, "/test/loadmodules"}.Example of how to assert that the configuration data is available and use it for an FTP session:
init_per_testcase(ftptest, Config) ->
{ok,_} = ct_ftp:open(ftp),
Config.
end_per_testcase(ftptest, _Config) ->
ct_ftp:close(ftp).
ftptest() ->
[{require,ftp,ftp_host},
{require,lm_directory}].
ftptest(Config) ->
Remote = filename:join(ct:get_config(lm_directory), "loadmodX"),
Local = filename:join(?config(priv_dir,Config), "loadmodule"),
ok = ct_ftp:recv(ftp, Remote, Local),
...An example of how the above functions could be rewritten if necessary to open multiple connections to the FTP server:
init_per_testcase(ftptest, Config) ->
{ok,Handle1} = ct_ftp:open(ftp_host),
{ok,Handle2} = ct_ftp:open(ftp_host),
[{ftp_handles,[Handle1,Handle2]} | Config].
end_per_testcase(ftptest, Config) ->
lists:foreach(fun(Handle) -> ct_ftp:close(Handle) end,
?config(ftp_handles,Config)).
ftptest() ->
[{require,ftp_host},
{require,lm_directory}].
ftptest(Config) ->
Remote = filename:join(ct:get_config(lm_directory), "loadmodX"),
Local = filename:join(?config(priv_dir,Config), "loadmodule"),
[Handle | MoreHandles] = ?config(ftp_handles,Config),
ok = ct_ftp:recv(Handle, Remote, Local),
...