-spec add_handler(HandlerId, Module, Config) -> ok | {error, term()}
               when
                   HandlerId :: logger_handler:id(),
                   Module :: module(),
                   Config :: logger_handler:config().

Add a handler with the given configuration.

HandlerId is a unique identifier which must be used in all subsequent calls referring to this handler.

-spec add_handler_filter(HandlerId, FilterId, Filter) -> ok | {error, term()}
                      when
                          HandlerId :: logger_handler:id(),
                          FilterId :: filter_id(),
                          Filter :: filter().

Add a filter to the specified handler.

The filter fun is called with the log event as the first parameter, and the specified filter_args() as the second parameter.

The return value of the fun specifies if a log event is to be discarded or forwarded to the handler callback:

• log_event/0 - The filter passed. The next handler filter, if any, is applied. If no more filters exist for this handler, the log event is forwarded to the handler callback.

• stop - The filter did not pass, and the log event is immediately discarded.

• ignore - The filter has no knowledge of the log event. The next handler filter, if any, is applied. If no more filters exist for this handler, the value of the filter_default configuration parameter for the handler specifies if the log event shall be discarded or forwarded to the handler callback.

See section Filters in the User's Guide for more information about filters.

Some built-in filters exist. These are defined in logger_filters.

-spec add_handlers(Application) -> ok | {error, term()} when Application :: atom();
            (HandlerConfig) -> ok | {error, term()} when HandlerConfig :: [config_handler()].

Reads the application configuration parameter logger and calls add_handlers/1 with its contents.

This function should be used by custom Logger handlers to make configuration consistent no matter which handler the system uses. Normal usage is to add a call to logger:add_handlers/1 just after the processes that the handler needs are started, and pass the application's logger configuration as the argument. For example:

-behaviour(application).
start(_, []) ->
    case supervisor:start_link({local, my_sup}, my_sup, []) of
        {ok, Pid} ->
            ok = logger:add_handlers(my_app),
            {ok, Pid, []};
        Error -> Error
     end.

This reads the logger configuration parameter from the my_app application and starts the configured handlers. The contents of the configuration use the same rules as the logger handler configuration.

If the handler is meant to replace the default handler, the Kernel's default handler have to be disabled before the new handler is added. A sys.config file that disables the Kernel handler and adds a custom handler could look like this:

[{kernel,
  [{logger,
    %% Disable the default Kernel handler
    [{handler, default, undefined}]}]},
 {my_app,
  [{logger,
    %% Enable this handler as the default
    [{handler, default, my_handler, #{}}]}]}].

-spec add_primary_filter(FilterId, Filter) -> ok | {error, term()}
                      when FilterId :: filter_id(), Filter :: filter().

Add a primary filter to Logger.

The filter fun is called with the log event as the first parameter, and the specified filter_args() as the second parameter.

The return value of the fun specifies if a log event is to be discarded or forwarded to the handlers:

• log_event/0 - The filter passed. The next primary filter, if any, is applied. If no more primary filters exist, the log event is forwarded to the handler part of Logger, where handler filters are applied.

• stop - The filter did not pass, and the log event is immediately discarded.

• ignore - The filter has no knowledge of the log event. The next primary filter, if any, is applied. If no more primary filters exist, the value of the primary filter_default configuration parameter specifies if the log event shall be discarded or forwarded to the handler part.

See section Filters in the User's Guide for more information about filters.

Some built-in filters exist. These are defined in logger_filters.

-spec get_config() ->
              #{primary => primary_config(),
                handlers => [logger_handler:config()],
                proxy => olp_config(),
                module_levels => [{module(), level() | all | none}]}.

Look up all current Logger configuration, including primary, handler, and proxy configuration, and module level settings.

-spec get_handler_config() -> [Config] when Config :: logger_handler:config().

Look up the current configuration for all handlers.

-spec get_handler_config(HandlerId) -> {ok, Config} | {error, term()}
                      when HandlerId :: logger_handler:id(), Config :: logger_handler:config().

Look up the current configuration for the given handler.

-spec get_handler_ids() -> [HandlerId] when HandlerId :: logger_handler:id().

Look up the identities for all installed handlers.

-spec get_module_level() -> [{Module, Level}] when Module :: module(), Level :: level() | all | none.

Look up all current module levels. Returns a list containing one {Module,Level} element for each module for which the module level was previously set with set_module_level/2.

-spec get_module_level(Modules) -> [{Module, Level}]
                    when
                        Modules :: [Module] | Module,
                        Module :: module(),
                        Level :: level() | all | none.

Look up the current level for the given modules. Returns a list containing one {Module,Level} element for each of the given modules for which the module level was previously set with set_module_level/2.

-spec get_primary_config() -> Config when Config :: primary_config().

Look up the current primary configuration for Logger.

-spec get_process_metadata() -> Meta | undefined when Meta :: metadata().

Retrieve data set with set_process_metadata/1 or update_process_metadata/1.

-spec get_proxy_config() -> Config when Config :: olp_config().

Look up the current configuration for the Logger proxy.

For more information about the proxy, see section Logger Proxy in the Kernel User's Guide.

-spec i() -> ok.

Pretty print all Logger configuration.

-spec i(What) -> ok when What :: primary | handlers | proxy | modules | logger_handler:id().

Pretty print the Logger configuration.

-spec remove_handler(HandlerId) -> ok | {error, term()} when HandlerId :: logger_handler:id().

Remove the handler identified by HandlerId.

-spec remove_handler_filter(HandlerId, FilterId) -> ok | {error, term()}
                         when HandlerId :: logger_handler:id(), FilterId :: filter_id().

Remove the filter identified by FilterId from the handler identified by HandlerId.

-spec remove_primary_filter(FilterId) -> ok | {error, term()} when FilterId :: filter_id().

Remove the primary filter identified by FilterId from Logger.

-spec set_application_level(Application, Level) -> ok | {error, not_loaded}
                         when Application :: atom(), Level :: level() | all | none.

Set the log level for all the modules of the specified application.

This function is a convenience function that calls logger:set_module_level/2 for each module associated with an application.

-spec set_handler_config(HandlerId, Config) -> ok | {error, term()}
                      when HandlerId :: logger_handler:id(), Config :: logger_handler:config().

Set configuration data for the specified handler. This overwrites the current handler configuration.

To modify the existing configuration, use update_handler_config/2, or, if a more complex merge is needed, read the current configuration with get_handler_config/1 , then do the merge before writing the new configuration back with this function.

If a key is removed compared to the current configuration, and the key is known by Logger, the default value is used. If it is a custom key, then it is up to the handler implementation if the value is removed or a default value is inserted.

-spec set_handler_config(HandlerId, level, Level) -> Return
                      when
                          HandlerId :: logger_handler:id(),
                          Level :: level() | all | none,
                          Return :: ok | {error, term()};
                  (HandlerId, filter_default, FilterDefault) -> Return
                      when
                          HandlerId :: logger_handler:id(),
                          FilterDefault :: log | stop,
                          Return :: ok | {error, term()};
                  (HandlerId, filters, Filters) -> Return
                      when
                          HandlerId :: logger_handler:id(),
                          Filters :: [{filter_id(), filter()}],
                          Return :: ok | {error, term()};
                  (HandlerId, formatter, Formatter) -> Return
                      when
                          HandlerId :: logger_handler:id(),
                          Formatter :: {module(), formatter_config()},
                          Return :: ok | {error, term()};
                  (HandlerId, config, Config) -> Return
                      when
                          HandlerId :: logger_handler:id(),
                          Config :: term(),
                          Return :: ok | {error, term()}.

Add or update configuration data for the specified handler. If the given Key already exists, its associated value will be changed to the given value. If it does not exist, it will be added.

If the value is incomplete, which for example can be the case for the config key, it is up to the handler implementation how the unspecified parts are set. For all handlers in the Kernel application, unspecified data for the config key is set to default values. To update only specified data, and keep the existing configuration for the rest, use update_handler_config/3.

See the definition of the logger_handler:config/0 type for more information about the different parameters.

-spec set_module_level(Modules, Level) -> ok | {error, term()}
                    when Modules :: [module()] | module(), Level :: level() | all | none.

Set the log level for the specified modules.

The log level for a module overrides the primary log level of Logger for log events originating from the module in question. Notice, however, that it does not override the level configuration for any handler.

For example: Assume that the primary log level for Logger is info, and there is one handler, h1, with level info and one handler, h2, with level debug.

With this configuration, no debug messages will be logged, since they are all stopped by the primary log level.

If the level for mymodule is now set to debug, then debug events from this module will be logged by the handler h2, but not by handler h1.

Debug events from other modules are still not logged.

To change the primary log level for Logger, use set_primary_config(level, Level).

To change the log level for a handler, use set_handler_config(HandlerId, level, Level) .

Note

The originating module for a log event is only detected if the key mfa exists in the metadata, and is associated with {Module, Function, Arity}. When log macros are used, this association is automatically added to all log events. If an API function is called directly, without using a macro, the logging client must explicitly add this information if module levels shall have any effect.

-spec set_primary_config(Config) -> ok | {error, term()} when Config :: primary_config().

Set primary configuration data for Logger. This overwrites the current configuration.

To modify the existing configuration, use update_primary_config/1, or, if a more complex merge is needed, read the current configuration with get_primary_config/0 , then do the merge before writing the new configuration back with this function.

If a key is removed compared to the current configuration, the default value is used.

-spec set_primary_config(level, Level) -> ok | {error, term()} when Level :: level() | all | none;
                  (filter_default, FilterDefault) -> ok | {error, term()}
                      when FilterDefault :: log | stop;
                  (filters, Filters) -> ok | {error, term()}
                      when Filters :: [{filter_id(), filter()}];
                  (metadata, Meta) -> ok | {error, term()} when Meta :: metadata().

Add or update primary configuration data for Logger. If the given Key already exists, its associated value will be changed to the given value. If it does not exist, it will be added.

-spec set_process_metadata(Meta) -> ok when Meta :: metadata().

Set metadata which Logger shall automatically insert in all log events produced on the current process.

Location data produced by the log macros, and/or metadata given as argument to the log call (API function or macro), are merged with the process metadata. If the same keys occur, values from the metadata argument to the log call overwrite values from the process metadata, which in turn overwrite values from the location data.

Subsequent calls to this function overwrites previous data set. To update existing data instead of overwriting it, see update_process_metadata/1.

-spec set_proxy_config(Config) -> ok | {error, term()} when Config :: olp_config().

Set configuration data for the Logger proxy. This overwrites the current proxy configuration. Keys that are not specified in the Config map gets default values.

To modify the existing configuration, use update_proxy_config/1, or, if a more complex merge is needed, read the current configuration with get_proxy_config/0 , then do the merge before writing the new configuration back with this function.

For more information about the proxy, see section Logger Proxy in the Kernel User's Guide.

-spec unset_application_level(Application) -> ok | {error, {not_loaded, Application}}
                           when Application :: atom().

Unset the log level for all the modules of the specified application.

This function is a utility function that calls logger:unset_module_level/2 for each module associated with an application.

-spec unset_module_level() -> ok.

Remove module specific log settings. After this, the primary log level is used for all modules.

-spec unset_module_level(Modules) -> ok when Modules :: [module()] | module().

Remove module specific log settings. After this, the primary log level is used for the specified modules.

-spec unset_process_metadata() -> ok.

Delete data set with set_process_metadata/1 or update_process_metadata/1.

-spec update_formatter_config(HandlerId, FormatterConfig) -> ok | {error, term()}
                           when
                               HandlerId :: logger_handler:id(),
                               FormatterConfig :: formatter_config().

Update the formatter configuration for the specified handler.

The new configuration is merged with the existing formatter configuration.

To overwrite the existing configuration without any merge, use

set_handler_config(HandlerId, formatter,
	      {FormatterModule, FormatterConfig}).

-spec update_formatter_config(HandlerId, Key, Value) -> ok | {error, term()}
                           when HandlerId :: logger_handler:id(), Key :: atom(), Value :: term().

Equivalent to update_formatter_config(HandlerId, #{Key => Value}).

-spec update_handler_config(HandlerId, Config) -> ok | {error, term()}
                         when HandlerId :: logger_handler:id(), Config :: logger_handler:config().

Update configuration data for the specified handler. This function behaves as if it was implemented as follows:

{ok, {_, Old}} = logger:get_handler_config(HandlerId),
logger:set_handler_config(HandlerId, maps:merge(Old, Config)).

To overwrite the existing configuration without any merge, use set_handler_config/2 .

-spec update_handler_config(HandlerId, level, Level) -> Return
                         when
                             HandlerId :: logger_handler:id(),
                             Level :: level() | all | none,
                             Return :: ok | {error, term()};
                     (HandlerId, filter_default, FilterDefault) -> Return
                         when
                             HandlerId :: logger_handler:id(),
                             FilterDefault :: log | stop,
                             Return :: ok | {error, term()};
                     (HandlerId, filters, Filters) -> Return
                         when
                             HandlerId :: logger_handler:id(),
                             Filters :: [{filter_id(), filter()}],
                             Return :: ok | {error, term()};
                     (HandlerId, formatter, Formatter) -> Return
                         when
                             HandlerId :: logger_handler:id(),
                             Formatter :: {module(), formatter_config()},
                             Return :: ok | {error, term()};
                     (HandlerId, config, Config) -> Return
                         when
                             HandlerId :: logger_handler:id(),
                             Config :: term(),
                             Return :: ok | {error, term()}.

Add or update configuration data for the specified handler. If the given Key already exists, its associated value will be changed to the given value. If it does not exist, it will be added.

If the value is incomplete, which for example can be the case for the config key, it is up to the handler implementation how the unspecified parts are set. For all handlers in the Kernel application, unspecified data for the config key is not changed. To reset unspecified data to default values, use set_handler_config/3.

See the definition of the logger_handler:config/0 type for more information about the different parameters.

-spec update_primary_config(Config) -> ok | {error, term()} when Config :: primary_config().

Update primary configuration data for Logger. This function behaves as if it was implemented as follows:

Old = logger:get_primary_config(),
logger:set_primary_config(maps:merge(Old, Config)).

To overwrite the existing configuration without any merge, use set_primary_config/1 .

-spec update_process_metadata(Meta) -> ok when Meta :: metadata().

Set or update metadata to use when logging from current process

If process metadata exists for the current process, this function behaves as if it was implemented as follows:

logger:set_process_metadata(maps:merge(logger:get_process_metadata(), Meta)).

If no process metadata exists, the function behaves as set_process_metadata/1 .

-spec update_proxy_config(Config) -> ok | {error, term()} when Config :: olp_config().

Update configuration data for the Logger proxy. This function behaves as if it was implemented as follows:

Old = logger:get_proxy_config(),
logger:set_proxy_config(maps:merge(Old, Config)).

To overwrite the existing configuration without any merge, use set_proxy_config/1 .

For more information about the proxy, see section Logger Proxy in the Kernel User's Guide.