CosEventChannelAdmin

CosEventChannelAdmin

The CosEventChannelAdmin defines a set if event service interfaces that enables decoupled asynchronous communication between objects and implements generic (untyped) version of the OMG COSS standard event service.

The event service defines two roles for objects: the supplier role and the consumer role. Suppliers supply event data to the event channel and consumers receive event data from the channel. Suppliers do not need to know the identity of the consumers, and vice versa. Consumers and suppliers are connected to the event channel via proxies, which are managed by ConsumerAdmin and SupplierAdmin objects.

There are four general models of communication. These are:

• The canonical push model. It allows the suppliers of events to initiate the transfer of event data to consumers. Event channels play the role of Notifier. Active suppliers use event channel to push data to passive consumers registered with the event channel.
• The canonical pull model. It allows consumers to request events from suppliers. Event channels play the role of Procure since they procure events on behalf of consumers. Active consumers can explicitly pull data from passive suppliers via the event channels.
• The hybrid push/pull model. It allows consumers request events queued at a channel by suppliers. Event channels play the role of Queue. Active consumers explicitly pull data deposited by active suppliers via the event channels.
• The hybrid pull/push model. It allows the channel to pull events from suppliers and push them to consumers. Event channels play the role of Intelligent agent. Active event channels can pull data from passive suppliers to push it to passive consumers.

To get access to all definitions, e.g., exceptions, include necessary hrl files by using:
-include_lib("cosEvent/include/*.hrl").

There are seven different interfaces supported in the service:

• ProxyPushConsumer
• ProxyPullSupplier
• ProxyPullConsumer
• ProxyPushSupplier
• ConsumerAdmin
• SupplierAdmin
• EventChannel

IDL specification for CosEventChannelAdmin:

#ifndef _COSEVENTCHANELADMIN_IDL
#define _COSEVENTCHANELADMIN_IDL

#include "CosEventComm.idl"

#pragma prefix "omg.org"

module CosEventChannelAdmin
{
  exception AlreadyConnected{};
  exception TypeError{};

  interface ProxyPushConsumer: CosEventComm::PushConsumer
  {
    void connect_push_supplier(in CosEventComm::
                               PushSupplier push_supplier) 
                               raises (AlreadyConnected);
  };

  interface ProxyPullSupplier: CosEventComm::PullSupplier
  {
    void connect_pull_consumer(in CosEventComm::
                               PullConsumer pull_consumer) 
                               raises (AlreadyConnected);
  };

  interface ProxyPullConsumer: CosEventComm::PullConsumer
  {
    void connect_pull_supplier(in CosEventComm::
                               PullSupplier pull_supplier) 
                               raises (AlreadyConnected, TypeError);
  };

  interface ProxyPushSupplier: CosEventComm::PushSupplier
  {
    void connect_push_consumer(in CosEventComm::
                               PushConsumer push_consumer) 
                               raises (AlreadyConnected, TypeError);
  };

  interface ConsumerAdmin
  {
    ProxyPushSupplier obtain_push_supplier();
    ProxyPullSupplier obtain_pull_supplier();
  };

  interface SupplierAdmin
  {
    ProxyPushConsumer obtain_push_consumer();
    ProxyPullConsumer obtain_pull_consumer();
  };

  interface EventChannel
  {
    ConsumerAdmin for_consumers();
    SupplierAdmin for_suppliers();
    void destroy();
  };

};

#endif


                

support - support@erlang.ericsson.se