Expressions

6 Expressions
In this chapter, all valid Erlang expressions are listed. When writing Erlang programs, it is also allowed to use macro- and record expressions. However, these expressions are expanded during compilation and are in that sense not true Erlang expressions. Macro- and record expressions are covered in separate chapters: Macros and Records.
6.1 Expression Evaluation
All subexpressions are evaluated before an expression itself is evaluated, unless explicitly stated otherwise. For example, consider the expression:
Expr1 + Expr2
    
Expr1 and Expr2, which are also expressions, are evaluated first - in any order - before the addition is performed.
Many of the operators can only be applied to arguments of a certain type. For example, arithmetic operators can only be applied to numbers. An argument of the wrong type will cause a badarg run-time error.
6.2 Terms
The simplest form of expression is a term, that is an integer, float, atom, string, list or tuple. The return value is the term itself.
6.3 Variables
A variable is an expression. If a variable is bound to a value, the return value is this value. Unbound variables are only allowed in patterns.
Variables start with an uppercase letter or underscore (_) and may contain alphanumeric characters, underscore and @. Examples:
X
Name1
PhoneNumber
Phone_number
_
_Height
    
Variables are bound to values using pattern matching. Erlang uses single assignment, a variable can only be bound once.
The anonymous variable is denoted by underscore (_) and can be used when a variable is required but its value can be ignored. Example:
[H|_] = [1,2,3]
    
Variables starting with underscore (_), for example _Height, are normal variables, not anonymous. They are however ignored by the compiler in the sense that they will not generate any warnings for unused variables. Example: The following code
member(_, []) ->
    [].
    
can be rewritten to be more readable:
member(Elem, []) ->
    [].
    
This will however cause a warning for an unused variable Elem, if the code is compiled with the flag warn_unused_vars set. Instead, the code can be rewritten to:
member(_Elem, []) ->
    [].
    
The scope for a variable is the body it is introduced in. Also, variables introduced in every branch of an if, case or receive expression are implicitly exported from this expression.
6.4 Patterns
A pattern has the same structure as a term but may contain unbound variables. Example:
Name1
[H|T]
{error,Reason}
    
Patterns are allowed in clause heads, case and receive expressions, and match expressions.
6.4.1 Match Operator = in Patterns
If Pattern1 and Pattern2 are valid patterns, then the following is also a valid pattern:
Pattern1 = Pattern2
      
When matched against a term, both Pattern1 and Pattern2 will be matched against the term. The idea behind this feature is to avoid reconstruction of terms. Example:
f({connect,From,To,Number,Options}, To) ->
    Signal = {connect,From,To,Number,Options},
    ...;
f(Signal, To) ->
    ignore.
      
can instead be written as
f({connect,_,To,_,_} = Signal, To) ->
    ...;
f(Signal, To) ->
    ignore.
      
6.4.2 String Prefix in Patterns
When matching strings, the following is a valid pattern:
f("prefix" ++ Str) -> ...
      
This is syntactic sugar for the equivalent, but harder to read
f([$p,$r,$e,$f,$i,$x | Str]) -> ...
      
6.4.3 Expressions in Patterns
An arithmetic expression can be used within a pattern, if it uses only numeric or bitwise operators, and if its value can be evaluated to a constant at compile-time. Example:
case {Value, Result} of
    {?THRESHOLD+1, ok} -> ...
      
This feature was added in Erlang 5.0/OTP R7.
6.5 Match
Expr1 = Expr2
    
Matches Expr1, a pattern, against Expr2. If the matching succeeds, any unbound variable in the pattern becomes bound and the value of Expr2 is returned.
If the matching fails, a badmatch run-time error will occur.
Examples:
1> {A, B} = {answer, 42}.
{answer,42}
2> A.
answer
3> {C, D} = [1, 2].
** exited: {{badmatch,[1,2]},[{erl_eval,expr,3}]} **
    
6.6 Function Calls
ExprF(Expr1,...,ExprN)
ExprM:ExprF(Expr1,...,ExprN)
    
ExprM should evalutate to a module name and ExprF to a function name or a fun.
When including the module name, the function is said to be called by using the fully qualified function name. This is often referred to as a remote or external function call.
The module name can be omitted, if ExprF evaluates to the name of a local function, an imported function, or an auto-imported BIF. Then the function is said to be called by using the implicitly qualified function name.
To avoid possible ambiguities, the fully qualified function name must be used when calling a function with the same name as a BIF, and the compiler does not allow defining a function with the same name as an imported function.
Note that when calling a local function, there is a difference between using the implicitly or fully qualified function name, as the latter always refer to the latest version of the module. See Compilation and Code Loading.
If ExprF evaluates to a fun, only the format ExprF(Expr1,...,ExprN) is correct.
See also the chapter about Function Evaluation.
6.7 If
if
    GuardSeq1 ->
        Body1;
    ...;
    GuardSeqN ->
        BodyN
end
    
The branches of an if-expression are scanned sequentially until a guard sequence GuardSeq which evaluates to true is found. Then the corresponding Body (sequence of expressions separated by ',') is evaluated.
The return value of Body is the return value of the if expression.
If no guard sequence is true, an if_clause run-time error will occur. If necessary, the guard expression true can be used in the last branch, as that guard sequence is always true.
Example:
is_greater_than(X, Y) ->
    if
        X>Y ->
            true;
        true -> % works as an 'else' branch
            false
    end
    
6.8 Case
case Expr of
    Pattern1 [when GuardSeq1] ->
        Body1;
    ...;
    PatternN [when GuardSeqN] ->
        BodyN
end
    
The expression Expr is evaluated and the patterns Pattern are sequentially matched against the result. If a match succeeds and the optional guard sequence GuardSeq is true, the corresponding Body is evaluated.
The return value of Body is the return value of the case expression.
If there is no matching pattern with a true guard sequence, a case_clause run-time error will occur.
Example:
is_valid_signal(Signal) ->
    case Signal of
        {signal, _What, _From, _To} ->
            true;
        {signal, _What, _To} ->
            true;
        _Else ->
            false
    end.
    
6.9 Send
Expr1 ! Expr2
    
Sends the value of Expr2 as a message to the process specified by Expr1. The value of Expr2 is also the return value of the expression.
Expr1 must evaluate to a pid, a registered name (atom) or a tuple {Name,Node}, where Name is an atom and Node a node name, also an atom.

If Expr1 evaluates to a name, but this name is not registered, a badarg run-time error will occur.

Sending a message to a pid never fails, even if the pid identifies a non-existing process.

Distributed message sending, that is if Expr1 evaluates to a tuple {Name,Node} (or a pid located at another node), also never fails.

6.10 Receive
receive
    Pattern1 [when GuardSeq1] ->
        Body1;
    ...;
    PatternN [when GuardSeqN] ->
        BodyN
end
    
Receives messages sent to the process using the send operator (!). The patterns Pattern are sequentially matched against the first message in time order in the mailbox, then the second, and so on. If a match succeeds and the optional guard sequence GuardSeq is true, the corresponding Body is evaluated. The matching message is consumed, that is removed from the mailbox, while any other messages in the mailbox remain unchanged.
The return value of Body is the return value of the receive expression.
receive never fails. Execution is suspended, possibly indefinitely, until a message arrives that does match one of the patterns and with a true guard sequence.
Example:
wait_for_onhook() ->
    receive
        onhook ->
            disconnect(),
            idle();
        {connect, B} ->
            B ! {busy, self()},
            wait_for_onhook()
    end.
    
It is possible to augment the receive expression with a timeout:
receive
    Pattern1 [when GuardSeq1] ->
        Body1;
    ...;
    PatternN [when GuardSeqN] ->
        BodyN
after
    ExprT ->
        BodyT
end
    
ExprT should evaluate to an integer. receive..after works exactly as receive, except that if no matching message has arrived within ExprT milliseconds, then BodyT is evaluated instead and its return value becomes the return value of the receive..after expression.
Example:
wait_for_onhook() ->
    receive
        onhook ->
            disconnect(),
            idle();
        {connect, B} ->
            B ! {busy, self()},
            wait_for_onhook();
    after
        60000 ->
            disconnect(),
            error()
    end.
    
It is legal to use a receive..after expression with no branches:
receive
after
    ExprT ->
        BodyT
end
    
This construction will not consume any messages, only suspend execution in the process for ExprT milliseconds and can be used to implement simple timers.
Example:
timer() ->
    spawn(m, timer, [self()]).

timer(Pid) ->
    receive
    after
        5000 ->
            Pid ! timeout
    end.
    
There are two special cases for the timeout value ExprT:

infinity

The process should wait indefinitely for a matching message -- this is the same as not using a timeout. Can be useful for timeout values that are calculated at run-time.

0

If there is no matching message in the mailbox, the timeout will occur immediately.

6.11 Term Comparisons
Expr1 op Expr2
    
op Description

== equal to

/= not equal to

=< less than or equal to

< less than

>= greater than or equal to

> greater than

=:= exactly equal to

=/= exactly not equal to

Term Comparison Operators.

The arguments may be of different data types. The following order is defined:
number < atom < reference < fun < port < pid < tuple < list < binary
    
Lists are compared element by element. Tuples are ordered by size, two tuples with the same size are compared element by element.
All comparison operators except =:= and =/= are of type coerce: When comparing an integer and a float, the integer is first converted to a float. In the case of =:= and =/=, there is no type conversion.
Returns the Boolean value of the expression, true or false.
Examples:
1> 1==1.0.
true
2> 1=:=1.0.
false
3> 1 > a.
false
    
6.12 Arithmetic Expressions
op Expr
Expr1 op Expr2
    
op Description Argument type

+ unary + number

- unary - number

+ number

- number

* number

/ floating point division number

bnot unary bitwise not integer

div integer division integer

rem integer remainder of X/Y integer

band bitwise and integer

bor bitwise or integer

bxor arithmetic bitwise xor integer

bsl arithmetic bitshift left integer

bsr bitshift right integer

Arithmetic Operators.

Examples:
1> +1.
1
2> -1.
-1
3> 1+1.
2
4> 4/2.
2.00000
5> 5 div 2.
2
6> 5 rem 2.
1
7> 2#10 band 2#01.
0
8> 2#10 bor 2#01.
3
    
6.13 Boolean Expressions
op Expr
Expr1 op Expr2
    
op Description

not unary logical not

and logical and

or logical or

xor logical xor

Logical Operators.

Examples:
1> not true.
false
2> true and false.
false
3> true xor false.
true
    
6.14 Short-Circuit Boolean Expressions
Expr1 orelse Expr2
Expr1 andalso Expr2
    
Boolean expressions where Expr2 is evaluated only if necessary. That is, Expr2 is evaluated only if Expr1 evaluates to false in an orelse expression, or only if Expr1 evaluates to true in an andalso expression. Returns the Boolean value of the expression, that is true or false.
Short-circuit boolean expressions are not allowed in guards. In guards, however, evaluation is always short-circuited since guard tests are known to be free of side effects.
Example 1:
case A >= -1.0 andalso math:sqrt(A+1) > B of
    
This will work even if A is less than -1.0, since in that case, math:sqrt/1 is never evaluated.
Example 2:
OnlyOne = is_atom(L) orelse
         (is_list(L) andalso length(L) == 1),
    
This feature was added in Erlang 5.1/OTP R8.
6.15 List Operations
Expr1 ++ Expr2
Expr1 -- Expr2
    
The list concatenation operator ++ appends its second argument to its first and returns the resulting list.
The list subtraction operator -- produces a list which is a copy of the first argument, subjected to the following procedure: for each element in the second argument, the first occurrence of this element (if any) is removed.
Example:
1> [1,2,3]++[4,5].
[1,2,3,4,5]
2> [1,2,3,2,1,2]--[2,1,2].
[3,1,2]
    
6.16 Bit Syntax Expressions
This chapter is under construction. Read about the bit syntax in Programming Examples.
6.17 Fun Expressions
fun
    (Pattern11,...,Pattern1N) [when GuardSeq1] ->
        Body1;
    ...;
    (PatternK1,...,PatternKN) [when GuardSeqK] ->
        BodyK
end
    
A fun expression begins with the keyword fun and ends with the keyword end. Between them should be a function declaration, similar to a regular function declaration, except that no function name is specified.
The return value of the expression is the resulting fun.
Examples:
1> Fun1 = fun (X) -> X+1 end.
#Fun<erl_eval.6.39074546>
2> Fun1(2).
3
3> Fun2 = fun (X) when X>=5 -> gt; (X) -> lt end.
#Fun<erl_eval.6.39074546>
4> Fun2(7).
gt
    
The following fun expression is also allowed:
fun Name/Arity
    
Name is an atom and Arity is an integer N which should specify an existing local function. The expression is syntactic sugar for:
fun (Arg1,...,ArgN) -> Name(Arg1,...,ArgN) end
    
More examples can be found in Programming Examples.
6.18 Catch and Throw
catch Expr
    
Returns the value of Expr unless a run-time error occurs during the evaluation. In that case, the error is caught and {'EXIT',{Reason,Stack}} is returned instead.
Reason depends on the type of error that occurred, and Stack is the stack of recent function calls, see Errors and Error Handling.
Examples:
1> catch 1+2.
3
2> catch 1+a.
{'EXIT',{badarith,[...]}}
    
Note that catch has low precedence and catch subexpressions often needs to be enclosed in brackets:
3> A = catch 1+2.
** 1: syntax error before: 'catch' **
4> A = (catch 1+2).
3
    
The BIF throw(Any) can be used for non-local return from a function. It must be evaluated within a catch, which will return the value Any. Example:
5> catch throw(hello).
hello
    
If throw/1 is not evaluated within a catch, a nocatch runtime error will occur.
6.19 Parenthesized Expressions
(Expr)
    
Parenthesized expressions are useful to override operator precedences, for example in arithmethic expressions:
1> 1 + 2 * 3.
7
2> (1 + 2) * 3.
9
    
6.20 Block Expressions
begin
   Expr1,
   ...,
   ExprN
end
    
Block expressions provide a way to group a sequence of expressions, similar to a clause body. The return value is the value of the last expression ExprN.
6.21 List Comprehensions
List comprehensions are a feature of many modern functional programming languages. Subject to certain rules, they provide a succinct notation for generating elements in a list.
List comprehensions are analogous to set comprehensions in Zermelo-Frankel set theory and are called ZF expressions in Miranda. They are analogous to the setof and findall predicates in Prolog.
List comprehensions are written with the following syntax:
[Expr || Qualifier1,...,QualifierN]
    
Expr is an arbitrary expression, and each Qualifier is either a generator or a filter.

A generator is written as:
Pattern <- ListExpr.
ListExpr must be an expression which evaluates to a list of terms.

A filter is an expression which evaluates to true or false.

The variables in the generator patterns shadow variables in the body surrounding the list comprehensions.
A list comprehension returns a list, where the elements are the result of evaluating Expr for each combination of generator list elements for which all filters are true.

Example:
1> [X*2 || X <- [1,2,3]].
[2,4,6]
    
More examples can be found in Programming Examples.
6.22 Guard Sequences
A guard sequence is a sequence of guards, separated by semicolon (;). The guard sequence is true if at least one of the guards is true.
Guard1;...;GuardK
A guard is a sequence of guard expressions, separated by comma (,). The guard is true if all guard expressions evaluate to true.
GuardExpr1,...,GuardExprN
The set of valid guard expressions (sometimes called guard tests) is a subset of the set of valid Erlang expressions. The reason for restricting the set of valid expressions is that evaluation of a guard expression must be guaranteed to be free of side effects. Valid guard expressions are:

the atom true,

other constants (terms and bound variables), all regarded as false,

calls to the BIFs specified below,

term comparisons,

arithmetic expressions, and

boolean expressions.

is_atom/1

is_binary/1

is_constant/1

is_float/1

is_function/1

is_integer/1

is_list/1

is_number/1

is_pid/1

is_port/1

is_reference/1

is_tuple/1

is_record/2

Type Test BIFs.

Note that each type test BIF has an older equivalent, without the is_ prefix. These old BIFs are retained for backwards compatibility only and should not be used in new code. They are also only allowed at top level. For example, they are not allowed in boolean expressions in guards.

abs(Number)

element(N, Tuple)

float(Term)

hd(List)

length(List)

node()

node(Pid|Ref|Port)

round(Number)

self()

size(Tuple|Binary)

tl(List)

trunc(Number)

Other BIFs Allowed in Guard Expressions.

6.23 Operator Precedence
Operator precedence in falling priority:

:

#

Unary + - bnot not

/ * div rem band and

+ - bor bxor bsl bsr or xor

++ --

== /= =< < >= > =:= =/=

andalso

orelse

= !

catch

When evaluating an expression, the operator with the highest priority is evaluated first. Operators with the same priority are evaluated left to right. Example:
6 + 5 * 4 - 3 / 2 evaluates to
6 + 20 - 1.5 evaluates to
26 - 1.5 evaluates to
24.5
    

op	Description
==	equal to
/=	not equal to
=<	less than or equal to
<	less than
>=	greater than or equal to
>	greater than
=:=	exactly equal to
=/=	exactly not equal to

op	Description	Argument type
+	unary +	number
-	unary -	number
+		number
-		number
*		number
/	floating point division	number
bnot	unary bitwise not	integer
div	integer division	integer
rem	integer remainder of X/Y	integer
band	bitwise and	integer
bor	bitwise or	integer
bxor	arithmetic bitwise xor	integer
bsl	arithmetic bitshift left	integer
bsr	bitshift right	integer

op	Description
not	unary logical not
and	logical and
or	logical or
xor	logical xor